Support cmake installation to any directory

Author: zhehangd

CMakeLists.txt

@@ -194,10 +194,11 @@ if (GODOT_CPP_SYSTEM_HEADERS)
 	set(GODOT_CPP_SYSTEM_HEADERS_ATTRIBUTE SYSTEM)
 endif ()
 
-target_include_directories(${PROJECT_NAME} ${GODOT_CPP_SYSTEM_HEADERS_ATTRIBUTE} PUBLIC
-	include
-	${CMAKE_CURRENT_BINARY_DIR}/gen/include
-	${GODOT_GDEXTENSION_DIR}
+target_include_directories(${PROJECT_NAME} ${GODOT_SYSTEM_HEADERS_ATTRIBUTE} PUBLIC
+	$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
+	$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/gen/include>
+	$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/${GODOT_GDEXTENSION_DIR}>
+	$<INSTALL_INTERFACE:include>
 )
 
 # Add the compile flags
@@ -227,26 +228,42 @@ set_target_properties(${PROJECT_NAME}
 		OUTPUT_NAME "${OUTPUT_NAME}"
 )
 
-install(TARGETS ${PROJECT_NAME} EXPORT godot_cpp_targets)
-
-# Export the target to the build directory.
+# Export the target to the install directory.
+#
+# Install after build
+# cmake --install build --prefix /path/to/install
+#
 # The target then can be imported by another cmake project like this:
 #   find_package(godot-cpp CONFIG REQUIRED)
 #
 #   add_library(libfoo SHARED)
 #   set_target_properties(libfoo PROPERTIES POSITION_INDEPENDENT_CODE ON)
-#   target_link_libraries(libfoo PUBLIC godot::godot-cpp)
+#   target_link_libraries(libfoo PUBLIC godot-cpp::godot-cpp)
 #
-# And user provides the build directory to cmake:
-#   -DCMAKE_PREFIX_PATH=<absolute-path-to-godot-cpp-build-dir>.
-
-export(EXPORT godot_cpp_targets
-	FILE "${PROJECT_BINARY_DIR}/cmake/godot-cpp.cmake"
-	NAMESPACE godot::
-)
+# And user provides the install directory to cmake:
+#   -DCMAKE_PREFIX_PATH=/absolute/path/to/install
 
+include(GNUInstallDirs)
 include(CMakePackageConfigHelpers)
+
+set(GODOT_CPP_PACKAGE_NAME godot-cpp) # the find_package name
+set(GODOT_CPP_PACKAGE_DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/${GODOT_CPP_PACKAGE_NAME}")
+
 configure_package_config_file(${PROJECT_SOURCE_DIR}/cmake/config.cmake.in
-	"${PROJECT_BINARY_DIR}/cmake/godot-cpp-config.cmake"
-	INSTALL_DESTINATION "lib/cmake/godot-cpp"
+	"${PROJECT_BINARY_DIR}/cmake/${GODOT_CPP_PACKAGE_NAME}-config.cmake"
+	INSTALL_DESTINATION "${GODOT_CPP_PACKAGE_DESTINATION}"
+)
+
+install(FILES ${PROJECT_BINARY_DIR}/cmake/${GODOT_CPP_PACKAGE_NAME}-config.cmake
+	DESTINATION ${GODOT_CPP_PACKAGE_DESTINATION}
 )
+
+install(TARGETS godot-cpp EXPORT godot_cpp_targets)
+install(DIRECTORY include/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
+install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/gen/include/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
+install(FILES ${GODOT_GDEXTENSION_DIR}/gdextension_interface.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
+
+install(EXPORT godot_cpp_targets
+	NAMESPACE godot-cpp::
+	FILE ${GODOT_CPP_PACKAGE_NAME}-targets.cmake
+	DESTINATION "${GODOT_CPP_PACKAGE_DESTINATION}")

cmake/config.cmake.in

@@ -1,5 +1,5 @@
 @PACKAGE_INIT@
 
-include("${CMAKE_CURRENT_LIST_DIR}/godot-cpp.cmake")
+include("${CMAKE_CURRENT_LIST_DIR}/godot-cpp-targets.cmake")
 
 check_required_components(godot-cpp)