|
| 1 | +{ self, pkgs }: |
| 2 | +let |
| 3 | + pname = "pgtap"; |
| 4 | + inherit (pkgs) lib; |
| 5 | + installedExtension = |
| 6 | + postgresMajorVersion: self.packages.${pkgs.system}."psql_${postgresMajorVersion}/exts/${pname}-all"; |
| 7 | + versions = postgresqlMajorVersion: (installedExtension postgresqlMajorVersion).versions; |
| 8 | + postgresqlWithExtension = |
| 9 | + postgresql: |
| 10 | + let |
| 11 | + majorVersion = lib.versions.major postgresql.version; |
| 12 | + pkg = pkgs.buildEnv { |
| 13 | + name = "postgresql-${majorVersion}-${pname}"; |
| 14 | + paths = [ |
| 15 | + postgresql |
| 16 | + postgresql.lib |
| 17 | + (installedExtension majorVersion) |
| 18 | + ]; |
| 19 | + passthru = { |
| 20 | + inherit (postgresql) version psqlSchema; |
| 21 | + lib = pkg; |
| 22 | + withPackages = _: pkg; |
| 23 | + }; |
| 24 | + nativeBuildInputs = [ pkgs.makeWrapper ]; |
| 25 | + pathsToLink = [ |
| 26 | + "/" |
| 27 | + "/bin" |
| 28 | + "/lib" |
| 29 | + ]; |
| 30 | + postBuild = '' |
| 31 | + wrapProgram $out/bin/postgres --set NIX_PGLIBDIR $out/lib |
| 32 | + wrapProgram $out/bin/pg_ctl --set NIX_PGLIBDIR $out/lib |
| 33 | + wrapProgram $out/bin/pg_upgrade --set NIX_PGLIBDIR $out/lib |
| 34 | + ''; |
| 35 | + }; |
| 36 | + in |
| 37 | + pkg; |
| 38 | +in |
| 39 | +self.inputs.nixpkgs.lib.nixos.runTest { |
| 40 | + name = pname; |
| 41 | + hostPkgs = pkgs; |
| 42 | + nodes.server = |
| 43 | + { config, ... }: |
| 44 | + { |
| 45 | + virtualisation = { |
| 46 | + forwardPorts = [ |
| 47 | + { |
| 48 | + from = "host"; |
| 49 | + host.port = 13022; |
| 50 | + guest.port = 22; |
| 51 | + } |
| 52 | + ]; |
| 53 | + }; |
| 54 | + services.openssh = { |
| 55 | + enable = true; |
| 56 | + }; |
| 57 | + |
| 58 | + services.postgresql = { |
| 59 | + enable = true; |
| 60 | + package = postgresqlWithExtension self.packages.${pkgs.system}.postgresql_15; |
| 61 | + }; |
| 62 | + |
| 63 | + specialisation.postgresql17.configuration = { |
| 64 | + services.postgresql = { |
| 65 | + package = lib.mkForce (postgresqlWithExtension self.packages.${pkgs.system}.postgresql_17); |
| 66 | + }; |
| 67 | + |
| 68 | + systemd.services.postgresql-migrate = { |
| 69 | + serviceConfig = { |
| 70 | + Type = "oneshot"; |
| 71 | + RemainAfterExit = true; |
| 72 | + User = "postgres"; |
| 73 | + Group = "postgres"; |
| 74 | + StateDirectory = "postgresql"; |
| 75 | + WorkingDirectory = "${builtins.dirOf config.services.postgresql.dataDir}"; |
| 76 | + }; |
| 77 | + script = |
| 78 | + let |
| 79 | + oldPostgresql = postgresqlWithExtension self.packages.${pkgs.system}.postgresql_15; |
| 80 | + newPostgresql = postgresqlWithExtension self.packages.${pkgs.system}.postgresql_17; |
| 81 | + oldDataDir = "${builtins.dirOf config.services.postgresql.dataDir}/${oldPostgresql.psqlSchema}"; |
| 82 | + newDataDir = "${builtins.dirOf config.services.postgresql.dataDir}/${newPostgresql.psqlSchema}"; |
| 83 | + in |
| 84 | + '' |
| 85 | + if [[ ! -d ${newDataDir} ]]; then |
| 86 | + install -d -m 0700 -o postgres -g postgres "${newDataDir}" |
| 87 | + ${newPostgresql}/bin/initdb -D "${newDataDir}" |
| 88 | + ${newPostgresql}/bin/pg_upgrade --old-datadir "${oldDataDir}" --new-datadir "${newDataDir}" \ |
| 89 | + --old-bindir "${oldPostgresql}/bin" --new-bindir "${newPostgresql}/bin" |
| 90 | + else |
| 91 | + echo "${newDataDir} already exists" |
| 92 | + fi |
| 93 | + ''; |
| 94 | + }; |
| 95 | + |
| 96 | + systemd.services.postgresql = { |
| 97 | + after = [ "postgresql-migrate.service" ]; |
| 98 | + requires = [ "postgresql-migrate.service" ]; |
| 99 | + }; |
| 100 | + }; |
| 101 | + }; |
| 102 | + testScript = |
| 103 | + { nodes, ... }: |
| 104 | + let |
| 105 | + pg17-configuration = "${nodes.server.system.build.toplevel}/specialisation/postgresql17"; |
| 106 | + in |
| 107 | + '' |
| 108 | + versions = { |
| 109 | + "15": [${lib.concatStringsSep ", " (map (s: ''"${s}"'') (versions "15"))}], |
| 110 | + "17": [${lib.concatStringsSep ", " (map (s: ''"${s}"'') (versions "17"))}], |
| 111 | + } |
| 112 | +
|
| 113 | + def run_sql(query): |
| 114 | + return server.succeed(f"""sudo -u postgres psql -t -A -F\",\" -c \"{query}\" """).strip() |
| 115 | +
|
| 116 | + def check_upgrade_path(pg_version): |
| 117 | + with subtest("Check ${pname} upgrade path"): |
| 118 | + firstVersion = versions[pg_version][0] |
| 119 | + server.succeed("sudo -u postgres psql -c 'DROP EXTENSION IF EXISTS ${pname};'") |
| 120 | + run_sql(f"""CREATE EXTENSION ${pname} WITH VERSION '{firstVersion}' CASCADE;""") |
| 121 | + installed_version = run_sql(r"""SELECT extversion FROM pg_extension WHERE extname = '${pname}';""") |
| 122 | + assert installed_version == firstVersion, f"Expected ${pname} version {firstVersion}, but found {installed_version}" |
| 123 | + for version in versions[pg_version][1:]: |
| 124 | + run_sql(f"""ALTER EXTENSION ${pname} UPDATE TO '{version}';""") |
| 125 | + installed_version = run_sql(r"""SELECT extversion FROM pg_extension WHERE extname = '${pname}';""") |
| 126 | + assert installed_version == version, f"Expected ${pname} version {version}, but found {installed_version}" |
| 127 | +
|
| 128 | + start_all() |
| 129 | +
|
| 130 | + server.wait_for_unit("multi-user.target") |
| 131 | + server.wait_for_unit("postgresql.service") |
| 132 | +
|
| 133 | + check_upgrade_path("15") |
| 134 | +
|
| 135 | + with subtest("Check ${pname} latest extension version"): |
| 136 | + server.succeed("sudo -u postgres psql -c 'DROP EXTENSION ${pname};'") |
| 137 | + server.succeed("sudo -u postgres psql -c 'CREATE EXTENSION ${pname} CASCADE;'") |
| 138 | + installed_extensions=run_sql(r"""SELECT extname, extversion FROM pg_extension;""") |
| 139 | + latestVersion = versions["15"][-1] |
| 140 | + assert f"${pname},{latestVersion}" in installed_extensions |
| 141 | +
|
| 142 | + with subtest("switch to postgresql 17"): |
| 143 | + server.succeed( |
| 144 | + "${pg17-configuration}/bin/switch-to-configuration test >&2" |
| 145 | + ) |
| 146 | +
|
| 147 | + with subtest("Check ${pname} latest extension version after upgrade"): |
| 148 | + installed_extensions=run_sql(r"""SELECT extname, extversion FROM pg_extension;""") |
| 149 | + latestVersion = versions["17"][-1] |
| 150 | + assert f"${pname},{latestVersion}" in installed_extensions |
| 151 | +
|
| 152 | + check_upgrade_path("17") |
| 153 | + ''; |
| 154 | +} |
0 commit comments