classes/class_primitivemesh

[giscus[bot]]

classes/class_primitivemesh

Inherits: Mesh< Resource< RefCounted< Object Inherited By: BoxMesh, CapsuleMesh, CylinderMesh, PlaneMesh, PointMesh, PrismMesh, RibbonTrailMesh, SphereMesh, TextMesh, TorusMesh, TubeTrailMesh Base ...

https://docs.godotengine.org/en/stable/classes/class_primitivemesh.html

[congxinUSC]

Trying to extend this class

Platform: Windows 11
Godot Version: 4.3 (dotnet)

About the virtual function _create_mesh_array(), according to the docs:

Override this method to customize how this primitive mesh should be generated. Should return an Array where each element is another Array of values required for the mesh (see the ArrayType constants).

However when I try to extend PrimitiveMesh or one of its subclasses it seems not working as expected.
Here's my code:

extends PrimitiveMesh
class_name MyUVSphereMesh

@export var rings: int = 32
@export var radial_segments: int = 64
@export var radius: float = 1

func _create_mesh_array() -> Array:
	var surface_array = []
	surface_array.resize(Mesh.ARRAY_MAX)

	# PackedVector**Arrays for mesh construction.
	var verts = PackedVector3Array()
	var uvs = PackedVector2Array()
	var normals = PackedVector3Array()
	var indices = PackedInt32Array()

	# Insert setting up the PackedVector**Arrays here.

	# Vertex indices.
	var thisrow = 0
	var prevrow = 0
	var point = 0

	# Loop over rings.
	for i in range(rings + 1):
		var v = float(i) / rings
		var w = sin(PI * v)
		var y = cos(PI * v)

		# Loop over segments in ring.
		for j in range(radial_segments + 1):
			var u = float(j) / radial_segments
			var x = sin(u * PI * 2.0)
			var z = cos(u * PI * 2.0)
			var vert = Vector3(x * radius * w, y * radius, z * radius * w)
			verts.append(vert)
			normals.append(vert.normalized())
			uvs.append(Vector2(u, v))
			point += 1

			# Create triangles in ring using indices.
			if i > 0 and j > 0:
				indices.append(prevrow + j - 1)
				indices.append(prevrow + j)
				indices.append(thisrow + j - 1)

				indices.append(prevrow + j)
				indices.append(thisrow + j)
				indices.append(thisrow + j - 1)

		prevrow = thisrow
		thisrow = point

	# Assign arrays to surface array.
	surface_array[Mesh.ARRAY_VERTEX] = verts
	surface_array[Mesh.ARRAY_TEX_UV] = uvs
	surface_array[Mesh.ARRAY_NORMAL] = normals
	surface_array[Mesh.ARRAY_INDEX] = indices
	
	return surface_array

Basically it's just re-implementing a UV sphere according to the ArrayMesh tutorial.
When I try to add this mesh class to a regular MeshInstance Node's mesh property, the editor alerts me with the error " _create_mesh_array must return at least a vertex array."
After a little more exploration it seems that my code didn't actually override this function properly (and it's still trying to call the default implementation which I believe just returns an empty array) though the built in gdscript editor shows the reference sign indicating that I DID override the function.
Is it that these classes actually can't be extended or I'm simply doing it wrong?

[Calinou]

The overridden method is called here: https://github.com/godotengine/godot/blob/15ff450680a40391aabbffde0a57ead2cd84db56/scene/resources/3d/primitive_meshes.cpp#L47-L49

If you make it a @tool script and put a print statement in _create_mesh_array(), do you see it in the editor Output panel after saving the scene and using Scene > Reload Saved Scene?

I believe it needs to be a @tool script in any case, or it won't work in the editor.

[congxinUSC]

It worked! Thanks!

Ah, so that's the catch, so even if it's a non-gameloop lifetime callback it still needs the @tool annotation to run in the editor. That's the part I was missing.
Without the annotation I can't even see simple print statement results and adding it makes it execute correctly.