Add batch files to execute Dotty commands on Windows

bin/common.bat

@@ -0,0 +1,115 @@
+@echo off
+setlocal enabledelayedexpansion
+
+rem # Wrapper for the published dotc/dotr script that check for file changes
+rem # and use sbt to re build the compiler as needed.
+
+rem ##########################################################################
+rem ## Environment setup
+
+set _BASENAME=%~n0
+
+set _EXITCODE=0
+
+for %%f in ("%~dp0..") do set _ROOT_DIR=%%~sf
+
+rem # Marker file used to obtain the date of latest call to sbt-back
+set _VERSION=%_ROOT_DIR%\dist-bootstrapped\target\pack\VERSION
+
+rem ##########################################################################
+rem ## Main
+
+rem # Create the target if absent or if file changed in ROOT/compiler
+call :new_files "%_VERSION%"
+
+if exist "%_VERSION%" if %_NEW_FILES%==0 goto target
+echo Building Dotty...
+pushd %_ROOT%
+sbt.bat "dist-bootstrapped/pack"
+popd
+
+:target
+call %*
+
+goto end
+
+rem ##########################################################################
+rem ## Subroutines
+
+rem input parameter: %1=version file
+rem Output parameter: _NEW_FILES
+:new_files
+set __VERSION_FILE=%~1
+
+call :timestamp "%__VERSION_FILE%"
+set __VERSION_TIMESTAMP=%_TIMESTAMP%
+
+set __JAVA_SOURCE_FILES=
+for /f %%i in ('dir /s /b "%_ROOT_DIR%compiler\*.java" 2^>NUL') do (
+    set __JAVA_SOURCE_FILES=!__JAVA_SOURCE_FILES! %%i
+)
+set __SCALA_SOURCE_FILES=
+for /f %%i in ('dir /s /b "%_ROOT_DIR%compiler\*.scala" 2^>NUL') do (
+    set __SCALA_SOURCE_FILES=!__SCALA_SOURCE_FILES! %%i
+)
+
+call :compile_required "%__VERSION_TIMESTAMP%" "%__JAVA_SOURCE_FILES% %__SCALA_SOURCE_FILES%"
+set _NEW_FILES=%_COMPILE_REQUIRED%
+
+goto :eof
+
+rem input parameter: 1=timestamp file 2=source files
+rem output parameter: _COMPILE_REQUIRED
+:compile_required
+set __TIMESTAMP_FILE=%~1
+set __SOURCE_FILES=%~2
+
+set __SOURCE_TIMESTAMP=00000000000000
+for %%i in (%__SOURCE_FILES%) do (
+    call :timestamp "%%i"
+    call :newer !_TIMESTAMP! !__SOURCE_TIMESTAMP!
+    if !_NEWER!==1 set __SOURCE_TIMESTAMP=!_TIMESTAMP!
+)
+if exist "%__TIMESTAMP_FILE%" ( set /p __CLASS_TIMESTAMP=<%__TIMESTAMP_FILE%
+) else ( set __CLASS_TIMESTAMP=00000000000000
+)
+
+call :newer %__SOURCE_TIMESTAMP% %__CLASS_TIMESTAMP%
+set _COMPILE_REQUIRED=%_NEWER%
+goto :eof
+
+rem output parameter: _NEWER
+:newer
+set __TIMESTAMP1=%~1
+set __TIMESTAMP2=%~2
+
+set __TIMESTAMP1_DATE=%__TIMESTAMP1:~0,8%
+set __TIMESTAMP1_TIME=%__TIMESTAMP1:~-6%
+
+set __TIMESTAMP2_DATE=%__TIMESTAMP2:~0,8%
+set __TIMESTAMP2_TIME=%__TIMESTAMP2:~-6%
+
+if %__TIMESTAMP1_DATE% gtr %__TIMESTAMP2_DATE% ( set _NEWER=1
+) else if %__TIMESTAMP1_DATE% lss %__TIMESTAMP2_DATE% ( set _NEWER=0
+) else if %__TIMESTAMP1_TIME% gtr %__TIMESTAMP2_TIME% ( set _NEWER=1
+) else ( set _NEWER=0
+)
+goto :eof
+
+rem input parameter: 1=file path
+rem output parameter: _TIMESTAMP
+:timestamp
+set __FILE_PATH=%~1
+
+set _TIMESTAMP=00000000000000
+for /f %%i in ('powershell -C "(Get-ChildItem '%__FILE_PATH%').LastWriteTime | Get-Date -uformat %%Y%%m%%d%%H%%M%%S"') do (
+    set _TIMESTAMP=%%i
+)
+goto :eof
+
+rem ##########################################################################
+rem ## Cleanups
+
+:end
+exit /b %_EXITCODE%
+endlocal

bin/dotc.bat

@@ -0,0 +1,6 @@
+@echo off
+setlocal
+
+for %%f in ("%~dp0..") do set _ROOT_DIR=%%~sf
+
+call %_ROOT_DIR%\bin\common.bat "%_ROOT_DIR%\dist-bootstrapped\target\pack\bin\dotc.bat" %*

bin/dotd.bat

@@ -0,0 +1,6 @@
+@echo off
+setlocal
+
+for %%f in ("%~dp0..") do set _ROOT_DIR=%%~sf
+
+call %_ROOT_DIR%\bin\common.bat "%_ROOT_DIR%\dist-bootstrapped\target\pack\bin\dotd.bat" %*

bin/dotr.bat

@@ -0,0 +1,6 @@
+@echo off
+setlocal
+
+for %%f in ("%~dp0..") do set _ROOT_DIR=%%~sf
+
+call %_ROOT_DIR%\bin\common.bat "%_ROOT_DIR%\dist-bootstrapped\target\pack\bin\dotr.bat" %*

dist/bin/common.bat

@@ -0,0 +1,65 @@
+rem ##########################################################################
+rem ## Code common to dotc.bat, dotd.bat and dotr.bat
+
+if defined JAVACMD (
+    set _JAVACMD=%JAVACMD%
+) else if defined JAVA_HOME (
+    set _JAVACMD=%JAVA_HOME%\bin\java.exe
+) else if defined JDK_HOME (
+    set _JAVACMD=%JDK_HOME%\bin\java.exe
+) else (
+    where /q java.exe
+    if !ERRORLEVEL!==0 (
+        set __JAVA_BIN_DIR=
+        for /f "delims=" %%i in ('where /f java.exe') do (
+            set __PATH=%%~dpsi
+            rem we take first occurence and ignore Oracle path for java executable
+            if not defined __JAVA_BIN_DIR if "!__PATH!"=="!__PATH:javapath=!" set __JAVA_BIN_DIR=!__PATH!
+        )
+        if defined __JAVA_BIN_DIR set _JAVACMD=!__JAVA_BIN_DIR!\java.exe
+    )
+    if not defined _JAVACMD (
+        set _PATH=C:\Progra~1\Java
+        for /f %%f in ('dir /ad /b "!_PATH!\jre*" 2^>NUL') do set _JAVA_HOME=!_PATH!\%%f
+        if not defined _JAVA_HOME (
+           set _PATH=C:\opt
+           for /f %%f in ('dir /ad /b "!_PATH!\jdk*" 2^>NUL') do set _JAVA_HOME=!_PATH!\%%f\jre
+        )
+        if defined _JAVA_HOME (
+            set _JAVACMD=!_JAVA_HOME!\bin\java.exe
+        )
+    )
+)
+if not exist "%_JAVACMD%" (
+   echo Error: Java executable not found ^(%_JAVACMD%^) 1>&2
+   set _EXITCODE=1
+   goto :eof
+)
+
+if defined DOTTY_HOME (
+    set _LIB_DIR=%DOTTY_HOME%\lib
+) else (
+    if not defined _PROG_HOME (
+        for %%f in ("%~dp0..") do set _PROG_HOME=%%~sf
+    )
+    set _LIB_DIR=!_PROG_HOME!\lib
+)
+
+set _PSEP=;
+
+for /f %%f in ('dir /a-d /b "%_LIB_DIR%\*dotty-compiler*"')       do set _DOTTY_COMP=%_LIB_DIR%\%%f
+for /f %%f in ('dir /a-d /b "%_LIB_DIR%\*dotty-interfaces*"')     do set _DOTTY_INTF=%_LIB_DIR%\%%f
+for /f %%f in ('dir /a-d /b "%_LIB_DIR%\*dotty-library*"')        do set _DOTTY_LIB=%_LIB_DIR%\%%f
+for /f %%f in ('dir /a-d /b "%_LIB_DIR%\*dotty-staging*"')        do set _DOTTY_STAGING=%_LIB_DIR%\%%f
+for /f %%f in ('dir /a-d /b "%_LIB_DIR%\*scala-asm*"')            do set _SCALA_ASM=%_LIB_DIR%\%%f
+for /f %%f in ('dir /a-d /b "%_LIB_DIR%\*scala-library*"')        do set _SCALA_LIB=%_LIB_DIR%\%%f
+rem removed since version 0.16.x (#5597)
+rem for /f %%f in ('dir /a-d /b "%_LIB_DIR%\*scala-xml*"')            do set _SCALA_XML=%_LIB_DIR%\%%f
+for /f %%f in ('dir /a-d /b "%_LIB_DIR%\*compiler-interface*"')   do set _SBT_INTF=%_LIB_DIR%\%%f
+for /f %%f in ('dir /a-d /b "%_LIB_DIR%\*jline-reader-3*"')       do set _JLINE_READER=%_LIB_DIR%\%%f
+for /f %%f in ('dir /a-d /b "%_LIB_DIR%\*jline-terminal-3*"')     do set _JLINE_TERMINAL=%_LIB_DIR%\%%f
+for /f %%f in ('dir /a-d /b "%_LIB_DIR%\*jline-terminal-jna-3*"') do set _JLINE_TERMINAL_JNA=%_LIB_DIR%\%%f
+for /f %%f in ('dir /a-d /b "%_LIB_DIR%\*jna-4*"')                do set _JNA=%_LIB_DIR%\%%f
+
+rem debug
+set _DEBUG_STR=-agentlib:jdwp=transport=dt_socket,server=y,suspend=y,address=5005

dist/bin/dotc.bat

@@ -0,0 +1,143 @@
+@echo off
+setlocal enabledelayedexpansion
+
+rem ##########################################################################
+rem ## Environment setup
+
+set _EXITCODE=0
+
+set _BASENAME=%~n0
+
+for %%f in ("%~dp0..") do set _PROG_HOME=%%~sf
+
+call %_PROG_HOME%\bin\common.bat
+if not %_EXITCODE%==0 goto end
+
+set _COMPILER_MAIN=dotty.tools.dotc.Main
+set _DECOMPILER_MAIN=dotty.tools.dotc.decompiler.Main
+set _REPL_MAIN=dotty.tools.repl.Main
+
+set _PROG_NAME=%_COMPILER_MAIN%
+
+call :args %*
+
+rem ##########################################################################
+rem ## Main
+
+call :classpathArgs
+
+if defined JAVA_OPTS ( set _JAVA_OPTS=%JAVA_OPTS%
+) else ( set _JAVA_OPTS=-Xmx768m -Xms768m
+)
+"%_JAVACMD%" %_JAVA_OPTS% %_JAVA_DEBUG% %_JAVA_ARGS% %_JVM_CP_ARGS% ^
+-Dscala.usejavacp=true ^
+%_PROG_NAME% %_SCALA_ARGS% %_RESIDUAL_ARGS%
+if not %ERRORLEVEL%==0 (
+    set _EXITCODE=1
+    goto end
+)
+goto end
+
+rem ##########################################################################
+rem ## Subroutines
+
+:args
+set _JAVA_DEBUG=
+set _HELP=
+set _VERBOSE=
+set _QUIET=
+set _SCALA_ARGS=
+set _JAVA_ARGS=
+set _RESIDUAL_ARGS=
+
+:args_loop
+if "%~1"=="" goto args_done
+set "__ARG=%~1"
+if "%__ARG%"=="--" (
+    rem for arg; do addResidual "$arg"; done; set -- ;;
+) else if /i "%__ARG%"=="-h" (
+    set _HELP=true
+    call :addScala "-help"
+) else if /i "%__ARG%"=="-help" (
+    set _HELP=true
+    call :addScala "-help"
+) else if /i "%__ARG%"=="-v" (
+    set _VERBOSE=true
+    call :addScala "-verbose"
+) else if /i "%__ARG%"=="-verbose" (
+    set _VERBOSE=true
+    call :addScala "-verbose"
+) else if /i "%__ARG%"=="-debug" ( set _JAVA_DEBUG=%_DEBUG_STR%
+) else if /i "%__ARG%"=="-q" ( set _QUIET=true
+) else if /i "%__ARG%"=="-quiet" ( set _QUIET=true
+rem Optimize for short-running applications, see https://github.com/lampepfl/dotty/issues/222
+) else if "%__ARG%"=="-Oshort" (
+    call :addJava "-XX:+TieredCompilation -XX:TieredStopAtLevel=1"
+) else if /i "%__ARG%"=="-repl" ( set _PROG_NAME=%_REPL_MAIN%
+) else if /i "%__ARG%"=="-compile" ( set _PROG_NAME=%_COMPILER_MAIN%
+) else if /i "%__ARG%"=="-decompile" ( set _PROG_NAME=%_DECOMPILER_MAIN%
+) else if /i "%__ARG%"=="-print-tasty" (
+    set _PROG_NAME=%_DECOMPILER_MAIN%
+    call :addScala "-print-tasty"
+) else if /i "%__ARG%"=="-run" ( set _PROG_NAME=%_REPL_MAIN%
+) else if /i "%__ARG%"=="-with-compiler" ( set _JVM_CP_ARGS=%_PSEP%%_DOTTY_COMP%
+rem break out -D and -J options and add them to JAVA_OPTS as well
+rem so they reach the JVM in time to do some good. The -D options
+rem will be available as system properties.
+) else if "%__ARG:~0,2%"=="-D" ( call :addJava "%__ARG%"
+) else if "%__ARG:~0,2%"=="-J" ( call :addJava "%__ARG:~2%"
+) else ( call :addResidual "%__ARG%"
+)
+shift
+goto args_loop
+:args_done
+goto :eof
+
+rem output parameter: _SCALA_ARGS
+:addScala
+set _SCALA_ARGS=%_SCALA_ARGS% %~1
+goto :eof
+
+rem output parameter: _JAVA_ARGS
+:addJava
+set _JAVA_ARGS=%_JAVA_ARGS% %~1
+goto :eof
+
+rem output parameter: _RESIDUAL_ARGS
+:addResidual
+set _RESIDUAL_ARGS=%_RESIDUAL_ARGS% %~1
+goto :eof
+
+rem output parameter: _JVM_CP_ARGS
+:classpathArgs
+rem echo dotty-compiler: %_DOTTY_COMP%
+rem echo dotty-interface: %_DOTTY_INTF%
+rem echo dotty-library: %_DOTTY_LIB%
+rem echo scala-asm: %_SCALA_ASM%
+rem echo scala-lib: %_SCALA_LIB%
+rem echo sbt-intface: %_SBT_INTF%
+
+set __TOOLCHAIN=%_SCALA_LIB%%_PSEP%
+set __TOOLCHAIN=%__TOOLCHAIN%%_SCALA_ASM%%_PSEP%
+set __TOOLCHAIN=%__TOOLCHAIN%%_SBT_INTF%%_PSEP%
+set __TOOLCHAIN=%__TOOLCHAIN%%_DOTTY_INTF%%_PSEP%
+set __TOOLCHAIN=%__TOOLCHAIN%%_DOTTY_LIB%%_PSEP%
+set __TOOLCHAIN=%__TOOLCHAIN%%_DOTTY_COMP%%_PSEP%
+set __TOOLCHAIN=%__TOOLCHAIN%%_DOTTY_STAGING%%_PSEP%
+
+rem # jline
+set __TOOLCHAIN=%__TOOLCHAIN%%_JLINE_READER%%_PSEP%
+set __TOOLCHAIN=%__TOOLCHAIN%%_JLINE_TERMINAL%%_PSEP%
+set __TOOLCHAIN=%__TOOLCHAIN%%_JLINE_TERMINAL_JNA%%_PSEP%
+set __TOOLCHAIN=%__TOOLCHAIN%%_JNA%
+
+set _JVM_CP_ARGS=-classpath %__TOOLCHAIN%
+goto :eof
+
+rem ##########################################################################
+rem ## Cleanups
+
+:end
+exit /b %_EXITCODE%
+endlocal
+